Cara Menangani Data Ganda dengan Muncul Pesan pada Ms. Excel

Lagi-lagi membahas data ganda, ya karena Ms. Excel memang merupakan aplikasi pengolahan data dan data yang dientrikan tidak sedikit sehingga ada kemungkinan data ada yang ganda. Membahas data ganda memang sudah pernah saya posting sebelumnya namun kali ini saya akan memakan cara lain untuk mengatasi data ganda atau dengan kata lain duplikat data.

Cara yang saya pakai pada posting kali ini yaitu Excel akan menolak data jika data yang dientrikan memang benar-benar ganda atau sudah pernah dientrikan sebelumnya. Untuk menolak data ganda disini akan diinformasikan melalui sebuah pesan informasi bahwa data ganda telah dientrikan.

Baca :

Macro Excel || Memberi Tanda Ganda pada Excel

Pada posting terdahulu juga pernah saya bahas bagaimana cara mengatasi data ranking yang ganda dan tentunya ini bukan bahasa kali ini namun jika Anda membutuhkan materi kembali silakan simak dan baca kembali tulisan saya Rumus Rank Supaya Tidak Ganda pada Excel 2010 

Oke, pada artikel kali ini saya akan membuat prosedure pada worksheet_change artinya dimana ada perubahan pada worksheet maka koding akan dijalankan. Baiklah silakan copy pasteka coding dibawah ini untuk menolak data ganda dengan pesan pada worksheet1

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng As Range, r As Range, msg As String, x As Range
    Set rng = Intersect(Columns(1), Target)
    If Not rng Is Nothing Then
        Application.EnableEvents = False
        For Each r In rng
            If Not IsEmpty(r.Value) Then
                If Application.CountIf(Columns(1), r.Value) > 1 Then
                    msg = msg & vbLf & r.Address(0, 0) & vbTab & r.Value
                    If x Is Nothing Then
                        r.Activate
                        Set x = r
                    Else
                        Set x = Union(x, r)
                    End If
                End If
            End If
        Next
        If Len(msg) Then
            MsgBox "Data Ganda" & msg
            x.ClearContents
            x.Select
        End If
        Set rng = Nothing
        Set x = Nothing
        Application.EnableEvents = True
    End If
End Sub

Nah, setelah selesai silakan jalankan dan coba Anda entrikan data di kolom A dan coba dengan entri data yang sama maka sistem akan menolak data ganda dengan kata lain Excel akan memunculkan pesan data ganda pada alamat cell yang dianggap ganda.

Nah, ketika Anda mengetikan data nama AHMAD maka akan muncul sebuah pesan data ganda A5 "AHMAD" secara otomatis. Sebenarnya hal ini juga bisa dilakukan dengan menggunakan Validasi data (Data Validation" yang sudah disediakan pada menu Ms. Excel.

Okeh, itu saja semoga bermanfaat dan selamat mencoba.

Tweet